Dosyayı Linux ile düzenle

Question

Yardım ve destek için çok teşekkür ederim. Eh, aşağıdaki dosya:

name id alello chr pos snp  
s1  215  a 1 11 a215  
s1  216  a 1 11 a216  
s1  217  a 1 11 a217  
s1  218  a 1 11 a218  
s2  215  b 2 22 b215  
s2  216  b 2 22 b216  
s2  217  b 2 22 b217  
s2  218  b 2 22 b218 

ve dosya bu şekilde olması gerekiyor:

snp allelo chr pos 215  216  217 218  
s1  a 1 11 a215 a216 a217 a218  
s2  b 2 22 b215 b216 b217 b218 

, birisi bana yardım eder misiniz? Kurtarmaya çok teşekkürler

Answer 1

awk!

$ awk 'NR==1{h=$1 OFS $3 OFS $4 OFS $5; next} 
      {a[$1]=(($1 in a)?(a[$1] OFS $NF):($3 OFS $4 OFS $5 OFS $6)); 
      if(!($2 in b)) {h=h OFS $2; b[$2]}} 
     END{print h; for(k in a) print k,a[k]}' file | column -t 

name alello chr pos 215 216 217 218 
s1 a  1 11 a215 a216 a217 a218 
s2 b  2 22 b215 b216 b217 b218 

Answer 2

$ cat tst.awk 
NR == 1  { hdr = $1 OFS $3 OFS $4 OFS $5; next } 
!seen[$2]++ { hdr = hdr OFS $2 } 

$1 != prev { 
    if (++numRows > 1) { 
     if (numRows == 2) { 
      print hdr 
     } 
     print row 
    } 
    row = $1 OFS $3 OFS $4 OFS $5 
} 
{ row = row OFS $6; prev = $1 } 
END { print row } 

$ awk -f tst.awk file | column -t 
name alello chr pos 215 216 217 218 
s1 a  1 11 a215 a216 a217 a218 
s2 b  2 22 b215 b216 b217 b218 

bu irade çıkışı bir anda onlar girdi görünen sırayla satır ve sadece hafızada saklar bir satır senin girdi dosyası ne kadar büyük olursa olsun iyi çalışacak, böylece Not.