Çözümlenemedi: com.google.firebase: firebase-firestore: 11.4.2

Question

Yeni Firestore veritabanını, halihazırda "yükseltme" yapmak istediğim Gerçek Zamanlı Veri Tabanı dahil olmak üzere Firebase özelliklerini kullanan bir projede uygulamaya çalışıyorum .

this kılavuzuna göre çalışıyorum, ancak Firestore kitaplığını derlerken takılıyorum.

Bu benim mevcut proje gradle geçerli:

buildscript { 
    repositories { 
     jcenter() 

     maven { 
      url 'https://maven.google.com' 
     } 
    } 
    dependencies { 
     classpath 'com.android.tools.build:gradle:2.3.3' 
     classpath 'com.google.gms:google-services:3.1.0' 


    } 
} 

allprojects { 
    repositories { 
     jcenter() 
    } 
} 

task clean(type: Delete) { 
    delete rootProject.buildDir 
} 

Bu benim mevcut uygulama gradle geçerli:

apply plugin: 'com.android.application' 

android { 
    compileSdkVersion 25 
    buildToolsVersion "25.0.2" 
    defaultConfig { 
     applicationId "com.tal.wikirace" 
     minSdkVersion 23 
     targetSdkVersion 25 
     versionCode 1 
     versionName "1.0" 
     testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner" 
    } 
    buildTypes { 
     release { 
      minifyEnabled false 
      proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro' 
     } 
    } 
    productFlavors { 
    } 
} 

configurations { 
    compile.exclude group: "org.apache.httpcomponents", module: "httpclient" 
} 

dependencies { 
    compile fileTree(include: ['*.jar'], dir: 'libs') 
    androidTestCompile('com.android.support.test.espresso:espresso-core:2.2.2', { 
     exclude group: 'com.android.support', module: 'support-annotations' 
    }) 


    compile 'com.android.support.constraint:constraint-layout:1.0.2' 
    compile 'com.android.support.constraint:constraint-layout:1.0.2' 
    compile 'com.google.api-client:google-api-client:1.22.0' 
    compile'com.google.api-client:google-api-client-android:1.22.0' 
    compile 'com.android.support:appcompat-v7:25.3.1' 
    compile 'com.android.volley:volley:1.0.0' 
    compile 'com.google.code.gson:gson:2.7' 
    compile 'com.google.code.findbugs:jsr305:2.0.1' 
    compile 'com.google.http-client:google-http-client:1.18.0-rc' 
    compile 'com.android.support:design:25.3.1' 

    compile 'com.google.android.gms:play-services-auth:11.4.2' 
    compile 'com.google.firebase:firebase-auth:11.4.2' 
    compile 'com.google.firebase:firebase-database:11.4.2' 
    compile 'com.google.firebase:firebase-messaging:11.4.2' 
} 
apply plugin: 'com.google.gms.google-services' 

proje çalışıyor, ama bu çizgiyi eklemeye çalıştığınızda:

compile 'com.google.firebase:firebase-firestore:11.4.2' 

bu mesaj çıktı: Ben Android SDK Build-Tools, Google Play-Services ve Support Repository güncelledik

Failed To Resolve: com.google.firebase:firebase-firestore:11.4.2 

ama yardım etmedi.

Bunu nasıl düzeltebilirim?

Answer 1

Sen allprojects bloğunda google maven repo eksik:

allprojects { 
    repositories { 
     jcenter() 
     maven { 
      url 'https://maven.google.com' 
     } 
    } 
} 

Eğer Gradle 4.1 veya sonrası kullanıyorsanız, bunu kolaylaştırabilirsiniz:

allprojects { 
    repositories { 
     jcenter() 
     google() 
    } 
} 

allprojects depoları olan şeydir uygulamanızın modüllerini bulmak için kullanılır. Buildscript'te, sadece gradle eklentileri için modülleri bulur.

Ayrıca, Firebase modüllerinin hepsinin aynı sürümüne sahip olduğundan emin olmalısınız.