VBScript - Hata işleme kullanma

Question

Hataları yakalamak ve bunları kaydetmek için VBScript kullanmak istiyorum (yani "bir şeyleri günlüğe kaydet") ve komut dosyasının sonraki satırına devam et. Örneğin

,

 
On Error Resume Next 
'Do Step 1 
'Do Step 2 
'Do Step 3 

bir hata 1. adımda, bunu daha sonra 2. adımda bu mümkün mü devam hatayı log (ya da onunla başka özel işlevleri yerine) istediğiniz oluşursa

? ve bunu nasıl uygulayabilirim?

DÜZENLEME: Böyle bir şey yapabilir miyim?

 
On Error Resume myErrCatch 
'Do step 1 
'Do step 2 
'Do step 3 

myErrCatch: 
'log error 
Resume Next 

Answer 1

VBScript atma veya özel durumları yakalamak bir bağı yoktur, ancak çalışma zamanı gerçekleştirilen son operasyonda sonuçlarını içeren küresel bir Err nesnesi sağlar. Her işlemden sonra Err.Number özelliğinin sıfır olmadığını kontrol etmelisiniz.

On Error Resume Next 

DoStep1 

If Err.Number <> 0 Then 
    WScript.Echo "Error in DoStep1: " & Err.Description 
    Err.Clear 
End If 

DoStep2 

If Err.Number <> 0 Then 
    WScript.Echo "Error in DoStop2:" & Err.Description 
    Err.Clear 
End If 

'If you no longer want to continue following an error after that block's completed, 
'call this. 
On Error Goto 0 

"On Error Goto [etiket]" sözdizimi Applications (VBA) Visual Basic ve Visual Basic tarafından desteklenen, ancak olarak On Error Resume Next kullanmak zorunda VBScript bu dil özelliği desteklemiyor Yukarıda tarif edilen.

Answer 2

On Error Resume Next'un global olarak ayarlanmadığını unutmayın. Güvenli olmayan kod parçanızı, örneğin, bir hata oluştuğunda hemen kesilecek olan bir işleve koyabilirsiniz ve bu işlevi OERN nümerik emsali içeren alt listeden arayabilirsiniz.

ErrCatch() 

Sub ErrCatch() 
    Dim Res, CurrentStep 

    On Error Resume Next 

    Res = UnSafeCode(20, CurrentStep) 
    MsgBox "ErrStep " & CurrentStep & vbCrLf & Err.Description 

End Sub 

Function UnSafeCode(Arg, ErrStep) 

    ErrStep = 1 
    UnSafeCode = 1/(Arg - 10) 

    ErrStep = 2 
    UnSafeCode = 1/(Arg - 20) 

    ErrStep = 3 
    UnSafeCode = 1/(Arg - 30) 

    ErrStep = 0 
End Function